perm filename FILLZ.FAI[XX,LCS] blob
sn#223779 filedate 1976-07-06 generic text, type C, neo UTF8
COMMENT ⊗ VALID 00002 PAGES
C REC PAGE DESCRIPTION
C00001 00001
C00002 00002 TITLE FILL
C00026 ENDMK
C⊗;
TITLE FILL
ENTRY FILLER,LINES,EDIT
EXTERNAL .COMM.,ALF,RRJJ,SC,LPEN,MVBEAM,SCANR,UPDWN
EXTERNAL DST,SIZ,PLTR,DPY,AIVECT,AVECT
DEFINE FIXX(N)
< KIFIX N,N ↔ >
KK←2 ↔ L←3 ↔ LE←4 ↔ T←5 ↔ J←1
RL←6 ↔ RJ←7 ↔ B←0 ↔ H←11 ↔ JK←10
HG←12 ↔ D←13 ↔ AL←14 ↔ JJ←15
; SUBROUTINE FILLER(Q,M)
FILLER: 0
MOVEM 16,SV16#
HRRZ J,(16)
HRRZM J,SVQ#
HRRZ T,@1(16)
HRRZM T,SVM# ; KK=NE(1)
HRRZ KK,2(J)
ADDI KK,-1(J)
; DO 4 K=2,KK
HRRZI L,2(J)
; IF(NE(K).NE.3)GO TO 11
L4: ADDI L,3
HRRZ T,(L)
L11: SETZM (L)
CAIN T,3
; NE(K)=-1
SETOM (L)
; GO TO 4
; 11 NE(K)=0
; 4 CONTINUE
CAIGE L,(KK)
JRST L4
; RLFT=10000
MOVE RL,[=10000.0]
; RT=-10000
MOVN RJ,[=10000.0]
; B=RT
MOVE B,RJ
; DO 12 K=1,KK
HRRZI L,-3(J)
; H=IFIX(Q(K))
L12: ADDI L,3
KIFIX H,(L) ;MOVE H,(L)
FLTR H,H ;FLOAT(H)
; IF(H.LT.RLFT)RLFT=H
CAMGE H,RL
MOVE RL,H
; IF(H.GT.RT)RT=H
CAMLE H,RJ
MOVE RJ,H
; IF(H.EQ.B)NE(K)=-1
CAMN H,B
SETOM 2(L)
; B=H
MOVE B,H
; Q(K)=H
MOVEM H,(L)
; 12 R(K)=IFIX(R(K))
KIFIX T,1(L) ;MOVE T,1(L)
FLTR T,T ;FLOAT(T)
MOVEM T,1(L)
CAIGE L,-2(KK)
JRST L12
; NE(KK+1)=-1
SETOM 3(KK)
; LRT=RT
FIXX(RJ)
MOVEM RJ,LRT#
; JA=3
HRRZI T,3
HRRZM T,JA#
; 124 LEFT=RLFT
L124: KIFIX LE,RL ;MOVE LE,RL
; 51 J=LEFT
L51: MOVE J,LE
; 42 RJ=J+.001
L42: FLTR RJ,J ;MOVE RJ,J
FADR RJ,[=0.001]
; JCONT=0
SETZM JCONT#
; LEFT=J
MOVE LE,J
; JJ=-1
SETO JJ,
; ALT=-10000.
MOVN AL,[=10000.0]
; 200 DO 45 L=2,KK
HRRZ L,SVQ
L45: ADDI L,3
CAILE L,-2(KK)
JRST L455
; IF(NE(L).NE.0)GO TO 45
SKIPE 2(L)
JRST L45
; IF(MISS(L,RJ,Q))GO TO 45
CAML RJ,-3(L)
JRST L201
CAMLE RJ,(L)
JRST L202
L201: CAMGE RJ,(L)
CAMG RJ,-3(L)
JRST L45
; H=HGHT(L,RJ,Q,R)
L202: MOVE H,-2(L)
CAMN H,1(L)
JRST RET
MOVNS H
FADR H,1(L)
MOVE D,-3(L)
MOVNS T,D
FADR T,RJ
FADR D,(L)
FMPR H,T
FDVR H,D
FADR H,-2(L)
; IF(H.LT.ALT)GO TO 45
RET: CAMGE H,AL
JRST L45
; ALT=H
MOVE AL,H
; JJ=L
HRRZI JJ,(L)
; 45 CONTINUE
JRST L45
; IF(JJ)GO TO 43
L455: JUMPL JJ,L43
; JCONT=-1
SETOM JCONT
; LEFT=J
MOVE LE,J
; 46 JA=3
L46: HRRZI T,3
HRRZM T,JA
; JORD=-1
SETOM JORD#
; 52 KN=Q(JJ)
L52: KIFIX T,(JJ) ;MOVE T,(JJ)
MOVEM T,KN#
; KL=Q(JJ-1)
KIFIX T,-3(JJ) ;MOVE T,-3(JJ)
MOVEM T,KL#
; IF(KN.LT.KL)KN=KL
CAMLE T,KN
MOVEM T,KN
; 50 I=J
L50: MOVEM J,I#
; 102 RJ=I+.01
L102: FLTR RJ,I ;MOVE RJ,I
FADR RJ,[=0.1] ;6/11/75 ←←**↑↑ WAS 0.01 -- CHECK TIGHT CASES!!
; ALT=HGHT(JJ,RJ,Q,R)
MOVE AL,-2(JJ)
CAMN AL,1(JJ)
JRST RET2
MOVNS AL
FADR AL,1(JJ)
MOVE D,-3(JJ)
MOVNS T,D
FADR T,RJ
FADR D,(JJ)
FMPR AL,T
FDVR AL,D
FADR AL,-2(JJ)
; B=-10000
RET2: MOVN B,[=10000.0]
; JK=-1
SETO JK,
; XALT=ALT+.001
MOVE T,AL
FADR T,[=0.001]
MOVEM T,XALT#
; ZALT=ALT
MOVEM AL,ZALT#
; 400 DO 47 L=2,KK
MOVE L,SVQ
L47: ADDI L,3
CAILE L,-2(KK)
JRST L477
; IF(L.EQ.JJ.OR.MISS(L,RJ,Q).OR.NE(L).LT.0)GO TO 47
CAME L,JJ
SKIPGE 2(L)
JRST L47
CAML RJ,-3(L)
JRST L475
CAMLE RJ,(L)
JRST L476
L475: CAMGE RJ,(L)
CAMG RJ,-3(L)
JRST L47
; H=HGHT(L,RJ,Q,R)
L476: MOVE H,-2(L)
CAMN H,1(L)
JRST RET3
MOVNS H
FADR H,1(L)
MOVE D,-3(L)
MOVNS T,D
FADR T,RJ
FADR D,(L)
FMPR H,T
FDVR H,D
FADR H,-2(L)
; IF(H.GT.XALT)GO TO 47
RET3: CAMG H,XALT
; IF(H.LE.B)GO TO 47
CAMG H,B
JRST L47
; B=H
MOVE B,H
; JK=L
HRRZI JK,(L)
; 47 CONTINUE
JRST L47
; IF(JK)GO TO 48
L477: JUMPL JK,L48
; 300 IF(ZALT-B.GT..001.OR.I.NE.J)GO TO 59
MOVN T,B
FADR T,ZALT
CAMG T,[=0.001]
CAME J,I
JRST L59
; JX=Q(JK)
KIFIX T,(JK) ;MOVE T,(JK)
; IF(JX.GT.KN)GO TO 60
CAMLE T,KN
JRST L60
; JX=Q(JK-1)
KIFIX T,-3(JK) ;MOVE T,-3(JK)
; IF(JX.LT.KN)GO TO 59
CAMGE T,KN
JRST L59
; 60 L=JJ
L60: MOVE L,JJ
; JJ=JK
MOVE JJ,JK
; JK=L
MOVE JK,L
; KN=JX
MOVEM T,KN
; 59 IF(ALT-B.LT.2)GO TO 62
L59: MOVN T,B
FADR T,AL
CAMGE T,[=2.0]
JRST L62
; ALT=ALT-1
HRLZI T,576400
FADR AL,T
; B=B+1
HRLZI T,201400
FADR B,T
; 62 IF(JORD)GO TO 103
L62: SKIPGE JORD
JRST L103
; H=B
MOVE H,B
; B=ALT
MOVE B,AL
; ALT=H
MOVE AL,H
; IF(JK.NE.NK.AND.ABS(ALT-B).GT.5.)JA=3
CAMN JK,NK#
JRST L103
MOVN T,B
FADR T,AL
SKIPGE T
MOVNS T
CAMG T,[5.0]
JRST L103
HRRZI T,3
HRRZM T,JA
; 103 CALL LINES(RJ,ALT,JA)
L103: MOVEM RJ,SVRJ#
MOVEM AL,SVAL#
MOVEM B,SVB#
HRRZI 16,SVAC
BLT 16,SVAC+15
JSA 16,LINES
JUMP SVRJ
JUMP SVAL
JUMP JA
; 100 CALL LINES(RJ,B,2)
JSA 16,LINES
JUMP SVRJ
JUMP SVB
JUMP [2]
HRLZI 16,SVAC
BLT 16,15
; NK=JK
MOVEM JK,NK
; JORD=-JORD
MOVNS JORD
; NE(JK)=1
HRRZI T,1
HRRZM T,2(JK)
; NE(JJ)=-1
SETOM 2(JJ)
; JA=2
HRRZI T,2
HRRZM T,JA
; I=I+M
MOVE T,SVM
ADDB T,I
; IF(I.LT.KN)GO TO 102
CAMGE T,KN
JRST L102
; L=1
HRRZI L,3
; IF(KN.EQ.KL)L=-1
MOVE T,KN
CAMN T,KL
HRROI L,-3
; JJ=JJ+L
ADD JJ,L
; J=0
SETZ J,
; IF(L)J=-1
SKIPGE L
HRROI J,-3
; IF(KN+M.GT.Q(JJ+J).OR.JJ.GT.KK.OR.NE(JJ).NE.0)GO TO 124
SKIPN 2(JJ)
CAILE JJ,-2(KK)
JRST L124
ADD T,SVM
FLTR T,T
HRRZI HG,(JJ)
ADD HG,J
CAMLE T,(HG)
JRST L124
; J=I
MOVE J,I
; GO TO 52
JRST L52
; 48 JA=3
L48: HRRZI T,3
HRRZM T,JA
; 43 J=LEFT+M
L43: MOVE J,LE
ADD J,SVM
; IF(J.LE.LRT)GO TO 42
CAMG J,LRT
JRST L42
; IF(JCONT)GO TO 51
SKIPGE JCONT
JRST L51 ; END
MOVE 16,SV16
JRA 16,2(16)
SVAC: BLOCK 16
; SUBROUTINE LINES(A,B,L)
; COMMON/DST/BB,CC
; COMMON /SIZ/RSZ,JCEN,KCEN /FL/IC,NZ,NX,RZ,XGP
; COMMON/DL/IXRX,SAVER,AA /PLTR/IPLT,RHT,DIS
; COMMON R2,JA,CENTR,JB,RJQ(20),JQ(20)
; COMMON/DPY/JJ(4000),WDS(250),MEDIT,IGO
; EQUIVALENCE (ITOP,JJ(3999)),(IBOT,JJ(4000))
; 1,(JJ2,JJ(2))
; DATA BB/.008/,CC/3.5/
;C SET XGP TO 1200.0 FOR MARGIN IN XEROX COPIES
M←2 ↔ N←3 ↔ K←4
LINES: 0
; GO TO 23
JRST L23
;22 IF(JQ(1).NE.0)GO TO 23
L22: SKIPE PLTR+=27
JRST L23
; IF(CC.EQ.1000)GO TO 23
MOVSI T,212764
CAMN T,DST+1
JRST L23
; B=B*(CC-BB*ABS(A))
MOVE T,@(16)
MOVM T,T
FMPR T,DST
FSBR T,DST+1
FMPRM T,@1(16)
MOVNS @1(16)
;23 IF(IPLT)GO TO 2
; M=A*RSZ
L23: MOVE M,@(16)
FMPR M,SIZ
FIXX(M)
; N=B*RSZ
MOVE N,@1(16)
FMPR N,SIZ
FIXX(N)
; IF(RSZ.LE.0.8571)GO TO 3
MOVE T,[=0.8571]
CAML T,SIZ
;; JRST L3
JRST L6
SUB M,SIZ+1 ; M=M-JCEN
SUB N,SIZ+2 ; N=N-KCEN
; IF(JA.NE.8)GO TO 5
MOVEI T,10
CAME T,.COMM.+1
JRST L5
; IF(M.GT.511)M=511
CAMLE M,[=511]
HRRZI M,=511
; IF(M.LT.-511)M=-511
CAMGE M,[-=511]
HRROI M,-=511
;5 IF(IABS(M).GT.512)GO TO 77
L5: CAIG M,=512
CAMGE M,[-=512]
JRST L77
; IF(IABS(N).LT.512)GO TO 4
CAIGE N,=512
CAMG N,[-=512]
CAIA
JRST LL4
;77 KZ=-1
L77: SETOM KZ#
; RETURN
JRA 16,3(16)
;4 IF(KZ.EQ.0)GO TO 6
LL4: SKIPN KZ
JRST L6
; KZ=0
SETZM KZ
MOVEM M,MM# ; GO TO 1
MOVEM N,NN#
JRST L1
;3 IF(JA.EQ.44)GO TO 6
;6 IF(JJ2.GT.3990)RETURN
L6: MOVEI T,7626
CAMGE T,DPY+1
JRA 16,3(16)
; IF(L.EQ.3)GO TO 1
MOVEM M,MM
MOVEM N,NN
HRRZI T,3
CAMN T,@2(16)
JRST L1
; CALL AVECT(M,N)
JSA 16,AVECT
JUMP MM
JUMP NN
; RETURN
JRA 16,3(16)
;1 CALL AIVECT(M,N)
L1: JSA 16,AIVECT
JUMP MM
JUMP NN
; RETURN
JRA 16,3(16)
;2 IF(IPLT.EQ.-2)RETURN
;;L2: MOVNI T,2
;; CAMN T,PLTR
;; JRA 16,3(16)
EDIT: 0 ; 00100 SUBROUTINE EDIT(JJA)
; 00200 COMMON/ALF/INP(72),ML /UPDWN/ RL,UD
; 00300 COMMON /SC/JL,LJ,MK
;00400 1 ,ISKP,XMINUS,N,REXP,LK,NNUM,JM,JN,DBST,NFLG,IXX,ISEMI,QQ
; 00500 1 ,RVX(50),IAMP,A,RRN,B,MODE,IBLA
; 00600 COMMON R2,JA,CENTR,J2,RJQ(20),JQ(20)
; 00700 COMMON/RRJJ/RJJ2,RJJ(20)
;00800 EQUIVALENCE (RVX1,RVX(1)),(RVX2,RVX(2)),(RVX4,RVX(4))
;00900 1,(RVX3,RVX(3)),(RJ6,RJJ(4)),(RJ9,RJJ(7)),(R3,RJQ(1))
;01000 1,(RJ5,RJJ(3)),(RJ10,RJJ(8)),(INP2,INP(2)),(INP20,INP(20))
DEFINE JN<SC+=10> ↔ DEFINE ML <ALF+=72> ↔ DEFINE JA <.COMM.+1>
DEFINE R2<.COMM.> ↔ DEFINE RJJ2<RRJJ> ↔ DEFINE UD <UPDWN+1>
DEFINE RVX1<SC+=16> ↔ DEFINE RVX2<SC+=17> ↔ DEFINE RVX3<SC+=18>
DEFINE RVX4<SC+=19> ↔ DEFINE RJ6<RRJJ+4> ↔ DEFINE RJ5<RRJJ+3>
DEFINE RJ9<RRJJ+=7> ↔ DEFINE RJ10<RRJJ+=8> ↔ DEFINE R3<.COMM.+4>
DEFINE RJ8<RRJJ+=6> ↔ DEFINE RJ7<RRJJ+=5>
DEFINE INP2<ALF+1> ↔ DEFINE INP20<ALF+=19> ↔ DEFINE ISEMI<SC+=14>
DEFINE RL<UPDWN> ↔ DEFINE RJJ <RRJJ+1>
; 01100 JN=-1
SETOM JN
MOVE @(16)
MOVEM JJA#
; 01200 C THIS IS FLAG IN SCANR
; 01300 INP20=ISEMI
MOVE 02,ISEMI
MOVEM 02,INP20
; 01400 C SETS LIMIT IN SCANR
; 01500 ML=1
MOVEI 02,1
MOVEM 02,ML
; 01600 RVX2=0
SETZM RVX2
; 01700 RVX4=0
SETZM RVX4
;01800 C E=EDIT(55), C=COPY(2222), X=EXIT(222), DE=DEL(99), LP=LTPN
; 01900 CALL SCANR
JSA 16,SCANR
; 02000 JN=0
SETZM JN
; 02100 R2=RVX2
MOVE 3,RVX2
MOVEM 3,R2
; 02200 IF(RVX1.GT.10.)GO TO 7
MOVSI 02,204500
CAMGE 02,RVX1
JRST E7
; 02300 JA=0
SETZM JA
SETZ 0, ; FOR E8
; 02400 IF(RVX2.NE.0)GO TO 8
JUMPN 3,E8
; 02500 IF(INP2.EQ.'P')GO TO 5
MOVE 02,[501004020100]
CAMN 02,INP2
JRST E5
; 02600 RVX2=RL
MOVE 02,RL
; 02700 IF(RVX1.GT.2)RVX2=UD
MOVSI 202400
CAMGE RVX1
MOVE 02,UD
MOVEM 02,RVX2
; 02800 C STORES RT-LFT OR UP-DOWN INFO
; 02900 GO TO 8
JRST E8
; 03200 C FOR LIGHT PEN MOVING
E7: KIFIX 0,RVX1 ;MOVE RVX1 03300 7 JA=RVX1
MOVEM 00,JA
CAIN =99 ;03400 IF(JA.EQ.99)R2=0
SETZM R2
; 03500 IF(R2.NE.0)RETURN
SKIPE R2
JRA 16,1(16)
CAIE =55 ;03600 IF(JA.NE.55)RETURN
JRA 16,1(16)
; 03700 5 CALL LPEN(R3,R2,K)
E5: JSA 16,LPEN
JUMP R3
JUMP R2
JUMP 00,2 ; 2 IS A DUMMY HERE
; 03800 C ↑↑↑ K NOT USED!
;03900 CURSOR WILL FIND HORZ POS FOR 55 EDIT.(R3=STF,R2=HORZ) SEE 554 IN MAIN.
; 04000 IF(JA.EQ.0)CALL EXCH(R2,R3)
MOVE 0,JA
JUMPN 0,.+4
MOVE 2,R2
EXCH 2,R3
MOVEM 2,R2
; 04100 RVX1=2.
MOVSI 02,202400
MOVEM 02,RVX1
; 04200 RVX2=R3-RJJ(1)
MOVE 02,R3
FSBR 02,RJJ
MOVEM 02,RVX2
; 04300 RVX3=3.
MOVSI 02,202600
MOVEM 02,RVX3
; 04400 RJQ(2)=0
SETZM .COMM.+5 ; R4
; 04500 RJJ2=R2
MOVE 02,R2
MOVEM 02,RJJ2
; 04700 C SO JD WILL BE 0 IN MAIN PROG.
; 04800 C FOR EDIT MODE
E8: CAIN =55 ; 04900 8 IF(JA.EQ.55)RETURN
JRA 16,1(16)
; 05000 IF(INP2.EQ.'P')GO TO 17
MOVE 02,[501004020100]
CAMN 02,INP2
JRST E17
; 05100 IF(RVX1.GT.2)GO TO 117
MOVSI 02,202400
CAMGE 02,RVX1
JRST E117
; 05200 RL=RVX2
MOVE 02,RVX2
MOVEM 02,RL
SKIPE 2,RVX4 ; 05300 IF(RVX4.NE.0)UD=RVX4
MOVEM 02,UD
; 05400 GO TO 17
JRST E17
; 05500 117 IF(RVX4.NE.0)RL=RVX4
E117: MOVE 02,RVX4
JUMPE 02,.+3
MOVE 02,RVX4
MOVEM 02,RL
; 05600 UD=RVX2
MOVE 02,RVX2
MOVEM 02,UD
; 05700 17 R2=.00001
E17: MOVE 02,[0.00001]
MOVEM 02,R2
; 05800 JA=0
SETZM JA
KIFIX 1,RVX1 ;MOVE 1,RVX1 ; 5900 K=RVX1
;; MOVEM 00,K
; 06000 857 GO TO (1,2,3,4,2),K
;;E857: SKIPLE 1
;; CAILE 01,5
;; SKIPA 0
MOVE 7,JJA ; KEEP CODE NUM IN AC0
E857: JUMPLE 1,E1 ; IF(K.LE.0)K=1
CAIL 1,5
JRST E2 ; IF(K.GE.5)GO TO 2 -- CATCHES SOME ERRORS.
E855: JRST @E855 (1)
JUMP 00,E1
JUMP 00,E2
JUMP 00,E3
JUMP 00,E4
E4: MOVNS 00,RVX2 ; 06100 4 RVX2=-RVX2
E3: CAIE 7,4
JRST .+5 ; SKIP IF NOT CODE 4
SKIPN RJ6 ;06300 SKIP OVER CLEFS (JJA=3) IS NOW REMOVED. 6/73
SKIPE RJ5 ; 06400 3 CALL MVBEAM(RJJ,0,2,2,RVX2)
SKIPA
JRST E856 ; IGNORE BAR LINES -- IF(R5.EQ.0.AND.R6.EQ.0)GO TO 856
JSA 16,MVBEAM
JUMP RJJ
JUMP [0] ;MVBEAM USES AC0→6
JUMP [2]
JUMP [2]
JUMP RVX2
; 06500 C MOVES UP AND DOWN. HANDLES MINIS, ETC.
; ; 06600 IF(JJA.LT.4)GO TO 856
CAIGE 7,4
JRST E856
CAILE 7,6 ; 06700 IF(JJA.GT.6)GO TO 856
JRST E856
; 06800 C I THINK R2 MUST BE NON-ZERO TO WORK IN EDIT MODE?
; 06900 12 IF(RJ5.EQ.50)GO TO 856
MOVSI 02,206620
CAMN 02,RJ5
JRST E856
; 07000 C 50=CRESC.-DECRESC.
; 07300 RJ5=RJ5+RVX2
MOVE 02,RVX2
FADRM 02,RJ5
; 07400 C MOVES 5TH PARAM UP OR DOWN
JRST E856 ; 07500 GO TO 856
; 07600 1 RVX2=-RVX2
E1: MOVNS 00,RVX2
; 07700 2 R2=RVX2
E2: MOVE 02,RVX2
MOVEM 02,R2
; 07800 856 IF(RVX4.EQ.0)GO TO 858
E856: MOVE 3,RVX4
JUMPE 3,E858
KIFIX 1,RVX3 ;MOVE 1,RVX3 07900 K=RVX3
; 08000 RVX2=RVX4
MOVEM 3,RVX2
; 08100 RVX4=0
SETZM RVX4
; 08200 GO TO 857
JRST E857
; 08300 858 IF(R2.EQ..00001)GO TO 7515
E858: MOVE 2,R2
CAMN 2,[0.00001]
JRST E7515 ; 1 HAS R2
; 08400 IF(JJA.LT.5)GO TO 477
CAIGE 7,5
JRST E477
CAIG 7,=8 ; 08500 IF(JJA.LE.8)GO TO 5515
JRST E5515
E477: CAIE 7,4 ; 08600 477 IF(JJA.NE.4)GO TO 7515
JRST E7515
SKIPN RJ6 ; 08700 IF(RJ6.EQ.0)GO TO 7515
SKIPE RJ5 ; CHANGED↑↑↑ TO IF(RJ6.EQ.0.AND.RJ5.EQ.0)
SKIPA ;RARE CASES MIGHT BE FOUND! USING P7≠0
JRST E7515
; ; 08800 C ABOVE FOR P1=6 (BEAMS, SLURS, LINES)
E5515: SKIPE RJ6 ;IF(RJ6.EQ.0)SKIP //GO BACK (UP-DOWN)5515 RJ6=RJ6+R2
FADRM 2,RJ6
CAIN 7,6 ; 09000 IF(JJA.NE.6)GO TO 7515
SKIPN RJ9 ; 09100 IF(RJ9.EQ.0)GO TO 7515
JRST E7515
MOVE RJ10 ; 09200 IF(RJ10.NE.0)GO TO EDX1
CAML [30.0]
FADRM 2,RJ8 ; IF(RJ10.GE.30)RJ8=RJ8+R2
JUMPN E7515-1
SKIPN RJ8 ; IF(RJ8.NE.0)GO TO E7515-1
SKIPGE RJ7 ; IF(RJ7.GE.0))GO TO E7515
FADRM 2,RJ9 ; 09300 RJ9=RJ9+R2
;09400 RJ9(P9) IS LOC. OF INNER NOTE IN BEAM RANGE. SKIPS NUMBERS IN P9.
; 09500 7515 RJJ(1)=R2+RJJ(1)
E7515: FADRM 2,RJJ
JRA 16,1(16) ; 09600 END
END